Přejít na obsah

Nastavení cookies

Zvolte, které druhy cookies povolíte. Svou volbu můžete kdykoli změnit přes Nastavení cookies v dolní části každé stránky. Prohlášení o ochraně osobních údajů

Nezbytné

Vždy zapnuté

Potřebné pro přihlášení, uchování košíku a zapamatování vašich voleb. Jsou vždy zapnuté.

Které cookies?
  • weboke_sessie, weboke_klant, weboke_remember: vaše relace a trvalé přihlášení
  • weboke_basket: váš košík
  • wkBtwIncl: zobrazení cen s DPH nebo bez DPH
  • wok_cookies: vaše volba cookies, 12 měsíců

Měří, která reklama vede k návštěvě nebo objednávce, abychom neplatili za reklamy, které nic nepřinášejí.

Které cookies?
  • Google Ads přes Google Tag Manager (_gcl_au, _gcl_aw), až 90 dní
  • OpenAI Ads, reklamy v ChatGPT
  • wok_aff: partner, který vás k nám doporučil (partnerský program), 60 dní

4,6

Země a jazyk

Každá země má vlastní web s cenami a DPH dané země.

Zobrazit

Porovnání dvou seznamů: kdo je v jednom a chybí ve druhém?

Seznam členů proti platbám, loňští zákazníci proti letošním, skladový seznam proti objednávce: chcete zjistit, kdo je v jednom seznamu a ve druhém chybí. Vyhledání a odstranění duplicitních zákazníků hledá duplicity v rámci jednoho seznamu, zde porovnáte dva seznamy mezi sebou.

Jako příklad použijeme pekárnu Bakkerij De Korenaar se dvěma listy: Klanten2025 s e-mailovými adresami z loňského roku v A2:A8 a Klanten2026 s letošními adresami v A2:A7.

Způsob 1: pomocný sloupec s hodnotou odešel nebo zůstává

Na listu Klanten2025 zadejte do buňky B2:

=KDYŽ(COUNTIF(Klanten2026!$A$2:$A$7;A2)=0;"odešel";"zůstává")

Vzorec přetáhněte až k poslednímu zákazníkovi. Funkce COUNTIF spočítá, kolikrát se adresa vyskytuje v seznamu za rok 2026. Pokud je výsledek 0, zákazník odešel. Poté můžete sloupec B filtrovat nebo seřadit (viz Řazení a filtrování).

Znaky dolaru jsou důležité: bez nich se oblast ve druhém seznamu při přetahování posouvá a horní adresy z ní dole vypadnou.

Způsob 2: seznam obsahující pouze rozdíly

Na samostatném listu vytvoří funkce FILTER najednou seznam všech zákazníků, kteří odešli:

=FILTER(Klanten2025!A2:A8;COUNTIF(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"nikdo neodešel")

Zde funkce COUNTIF dostane jako druhý argument celý seznam a počítá výskyty pro každou adresu z roku 2025 současně. FILTER ponechá adresy, u kterých je výsledek 0. Nové zákazníky najdete tak, že seznamy prohodíte:

=FILTER(Klanten2026!A2:A7;COUNTIF(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"nikdo nový")

Odešlí a noví zákazníci vedle sebe
Zákazníci, kteří odešli (1), a noví zákazníci (2), každý seznam jediným vzorcem FILTER

Kdo je pouze v jednom z obou seznamů, ať nový, nebo odešlý, zjistíte takto:

=UNIQUE(SROVNAT.SVISLE(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

Funkce SROVNAT.SVISLE umístí oba seznamy pod sebe. Funkce UNIQUE s hodnotou 1 jako třetím argumentem ponechá jen hodnoty, které se vyskytují právě jednou. Pokud je některá adresa už v rámci jednoho seznamu dvakrát, nejprve tento seznam převeďte na jedinečné hodnoty: =UNIQUE(SROVNAT.SVISLE(UNIQUE(Klanten2025!A2:A8);UNIQUE(Klanten2026!A2:A7));;1).

Způsob 3: barvy místo seznamů

  1. Na listu Klanten2025 vyberte adresy, A2:A8.
  2. Na kartě Domů zvolte Podmíněné formátování, Nové pravidlo, typ Vzorec.
  3. Zadejte =COUNTIF(Klanten2026!$A$2:$A$7;$A2)=0, zvolte barvu výplně a klikněte na OK.

Odkaz na jiný list v pravidle formátování v Euro-Office normálně funguje, ve starších verzích Excelu to šlo jen přes definovaný název.

Zákazníci, kteří odešli, barevně zvýraznění
Adresy, které se v roce 2026 už nevyskytují, se zbarví oranžově, sloupec B uvádí, zda zákazník odešel, nebo zůstává

Na co si dát pozor

  • Mezery: „info@dekorenaar.nl “ s mezerou na konci je pro tabulku jiná adresa. Mezery nejprve odstraňte funkcí PROČISTIT v pomocném sloupci.
  • Prázdné buňky v oblasti se také počítají jako hodnota. Zahrňte proto jen řádky s daty, nebo prázdné buňky odfiltrujte pomocí <>"".
  • Čísla proti textu: pokud porovnáváte čísla zákazníků a v jednom seznamu je číslo uložené jako text (zarovnané v buňce vlevo) a ve druhém jako číslo, nenajdou se. Viz SVYHLEDAT vrací #N/A: jak to vyřešit.
  • Nezadávejte jako třetí argument funkce UNIQUE hodnotu PRAVDA bez závorek, Euro-Office zná pouze TRUE, PRAVDA() nebo 1 (viz Přebírání vzorců z Excelu: české názvy funkcí a středník).

Chvíli strpení…

Nastavení vašich domén

U každé domény nastavte jmenné servery, propojení s hostingem a to, kdo bude držitelem.

Načítání vašich domén…